用單片機模擬2272軟件解碼

在無線遙控領域，PT2262/2272是目前最常用的芯片之一，但由于芯片要求配對使用，在很大程度上影響了該芯片的使用，筆者從PT2262波形特征入手，結合應用實際，提出軟件解碼的方法和具體措施。

一、概述

PT2262/2272是一種CMOS工藝制造的低功耗低價位通用編解碼電路，是目前在無線通訊電路中作地址編碼識別最常用的芯片之一。

PT2262/2272最多可有12位(A0-A11)三態地址端管腳(懸空,接高電平,接低電平),任意組合可提供531441地址碼,PT2262最多可有6位(D0-D5)數據端管腳,設定的地址碼和數據碼從17腳串行輸出。

PT2262/2272必須用相同地址碼配對使用，當需要增加一個通訊機時，用戶不得不求助于技術人員或廠家來設置相同地址碼，客戶自己設置相對比較麻煩，尤其對不懂電子的人來說。隨著人們對操作的要求越來越高，PT2262/2272的這種配對使用嚴重制約著使用的方便性，人們不斷地要求使用一種無須請教專業人士，無須使用特殊工具，任何人都可以操作的方便的手段來彌補PT2262/2272的缺陷，這就是PT2262軟件解碼。

二、解碼原理

上面是PT2262的一段波形，可以看到一組一組的字碼，每組字碼之間有同步碼隔開，所以我們如果用單片機軟件解碼時，程序只要判斷出同步碼，然后對后面的字碼進行脈沖寬度識別即可。

2262每次發射時至少發射4組字碼，2272只有在連續兩次檢測到相同的地址碼加數據碼時才會把數據碼中的“1”驅動相應的數據輸出端為高電平和驅動VT端同步為高電平。因為無線發射的特點，第一組字碼非常容易受零電平干擾，往往會產生誤碼，所以程序可以丟棄處理。

下面我們來仔細看一下PT2262的波形特征：?

振蕩頻率 f=2*1000*16/Rosc(kΩ) kHz 其中Rosc為振蕩電阻 這里我們選用的是一種比較常用的頻率f≈10 kHz, Rosc=3.3MΩ(以下同)。下圖是振蕩頻率與碼位波形的對應關系：同步碼頭波形：

PT2262有三種編碼：0，1，和懸空(表示為f)。

1、 數據“0”發送的碼位如：

2、 數據“1”發送的碼位如：

3、 數據“f”發送的碼位如：

有了以上具體的波形，我們就可以進行軟件解碼了。T2262每次至少發送4次編碼，首先我們可以通過檢測11ms寬度的同步碼頭，有碼頭才開始進行編碼解碼，無碼頭則繼續等待。當收到碼頭時，還要檢測是否已經收到過碼頭，若無，則丟棄第一次編碼的信號，以防止誤碼。

從編碼圖中可以看出，每一位碼字都是從低電平開始到高電平，到低電平，再到高電平。為了檢測方便，在接收端我們把編碼信號進行了180°倒相，使碼位開始的上升沿轉化為下降沿，這樣當我們使用MCS51系列單片機解碼時可使用中斷方式及時截獲編碼。從編碼圖中還可以看出，每一位碼字都可以分成兩段，我們以每段中的電平寬度來描述碼位：

碼位 第一段 第二段 數值表示 反碼表示

??0???? 窄???? 窄??????00?????? 11

??1???? 寬???? 寬??????11?????? 00

??f???? 窄???? 寬??????01?????? 10

無效碼??寬???? 窄??????10?????? 01

軟件解碼方法1(反碼)：

從第一個下降沿開始延時700us左右，檢測電平高低，記為A1，再檢測第二個下降沿，延時700us左右，檢測電平高低，記為A2，這樣一個碼位就可以譯出來了，連續檢測12個碼位。

軟件解碼方法2(反碼)：

從第一個下降沿開始記時，并不斷檢測電平變化，一有電平變化，立即記錄電平寬度B1，再繼續記時直至出現第二個下降沿，記錄兩個下降沿的間隔B2，重復以上步驟，得到B3，B4，判斷B1，B2，B3，B4是否在各自允許的誤差范圍內，是則保存B1，B3，譯出一個碼位，否則認為誤碼，丟棄。連續正確檢測12個碼位。

兩種解碼方式各有優缺點如下：

??解碼方式????優點?????? 缺點

1 程序簡單，CPU開銷少 解碼精度差

2 程序復雜，CPU開銷大 解碼精度較高

為了獲得較高的解碼精度，我們推薦使用方法2，以避免大量的干擾信號的誤解碼。

三、參考解碼軟件

        ;軟件解碼程序(仿真PT2272) ;
        ;晶體頻率為11.0592Mhz ;
        ;本程序中的時間定位關系只適用于接3.3M振蕩電阻的PT2262解碼 ;
        ;使用其它阻值電阻時，應將定位時間按電阻比例縮放
        ;下面的程序中
        ;REM 為信號輸入端 ;
        ;RECEIVE 檢測到有效信號標志位 ;
        ;ENABLE_DETE 連續按鍵標志 ;
        ;3AH,3BH用作定時器 ; ;
        ;PT2262共12根地址線 ;
        ;31H,32H:接收的前8 位地址編碼 ;
        ;33H,30H:接收的后4 位地址編碼(若最后4位用作數據端，則只須讀第33H單元的內容即可) ;
        ;當用作數據端時，PT2262對應腳懸空被認為是低電平。
        ;地址數據說明 ;
        ;以31H.0 和32H.0 為例 ;
        ; 懸空 : 31H.0=0 32H.0=1 ;
        ;?? 1??: 31H.0=1 32H.0=1 ;
        ;?? 0??: 31H.0=0 32H.0=0 ;
        ; 出錯 : 31H.0=1 32H.0=0 ; ; ;
        ; 說明：為了能可靠檢測到有效信號，建議每次接收至少檢測3次，然后比較3次檢測值
        ;3次值相同才認為收到了正確信號?？稍谥鞒绦蛑腥缦绿幚恚旱?次檢測時調用REMOTE
        ;第2、3次檢測時調用REMOTES，請注意必需連續調用，否則得不到正確的數據 ; ;
        ;注意：將T1設定為16位定時器，允許中斷，否則將導致接收數據錯誤
REMOTE: CLR RECEIVE   ;;檢測50ms 內有沒有編碼接收 ;
        MOV 3AH,#55
REMOTEA:MOV 3BH,#250
REMOTEB:JB REM,REMOTE0;有碼發送則跳轉
        DJNZ 3BH,REMOTEB
        DJNZ 3AH,REMOTEA
REMOTE_END_1:
        CLR ENABLE_DETE
REMOTE_END:
        CLR REMOTING  ;清除探頭檢測標志
        RET
REMOTE0:JB ENABLE_DETE,REMOTE_END_1   ;按鍵沒有放開則返回
REMOTES:MOV 34H,#12   ;接收12位編碼 ;解碼 ; ;先找出接收碼的開頭即10ms左右的高電平 ;
        MOV TH1,#00H  ;;設置高電平時間為8~12ms ; ;檢測和等待8ms 的 低電平,70ms門限 ;
        CLR T_OVER
        MOV TL1,#00H
        SETB TR1
REMOTE1:MOV 3AH,#50
REMOTE2:MOV 3BH,#25
REMOTE3:JB REM,REMOTE1
        JB T_OVER,REMOTE_END
        DJNZ 3BH,REMOTE3
        DJNZ 3AH,REMOTE2      ;; ;等待在4ms 內接收到的高電平 ;
        CLR T_OVER
        MOV TH1,#0F1H
        MOV TL1,#0F0H
        SETB TR1
REMOTE_4:
        JB T_OVER,REMOTE_5
        JNB REM,REMOTE_4
        CLR TR1
        AJMP REMOTE6  ;;超出12ms 接收錯誤返回 ;
REMOTE_5:
        AJMP REMOTE_END
REMOTE6:MOV 3AH,#00   ;等待550us 后采集接收信號 ;
        DJNZ 3AH,$    ;;采集接收信號并記錄 ;
        MOV C,REM
        MOV A,33H
        RLC A
        MOV 33H,A
        MOV A,31H
        RLC A
        MOV 31H,A     ;;等待第二個上升沿,限時1.5ms ;
        CLR T_OVER
        MOV TH1,#0FAH
        MOV TL1,#099H
        SETB TR1
RM1:    JB T_OVER,REMOTE_END
        JB REM,RM1
        CLR TR1       ;;
        CLR T_OVER
        MOV TH1,#0FAH
        MOV TL1,#099H
        SETB TR1
RM2:    JB T_OVER,REMOTE_END
        JNB REM,RM2
        CLR TR1       ;;等待550us 后采集接收信號 ;
        MOV 3AH,#00
        DJNZ 3AH,$
        MOV C,REM
        MOV A,30H
        RLC A
        MOV 30H,A
        MOV A,32H
        RLC A
        MOV 32H,A     ;;等待第二個碼值的上升沿 ;
        CLR T_OVER
        MOV TH1,#0FAH
        MOV TL1,#099H
        SETB TR1
RM3:    JB T_OVER,RM5
        JB REM,RM3
        CLR TR1       ;;
        CLR T_OVER
        MOV TH1,#0FAH
        MOV TL1,#099H
        SETB TR1
RM4:    JB T_OVER,RM5
        JNB REM,RM4
        CLR TR1
        DJNZ 34H,REMOTE6      ;;把接收的編碼左移4 位將8 位密碼放在同一字節上
        MOV 34H,#4
        AJMP REMOTE7
RM5:    AJMP REMOTE_END
REMOTE7:CLR C
        MOV A,33H
        RLC A
        MOV 33H,A
        MOV A,31H
        RLC A
        MOV 31H,A
        CLR C
        MOV A,30H
        RLC A
        MOV 30H,A
        MOV A,32H
        RLC A
        MOV 32H,A
        DJNZ 34H,REMOTE7      ;;把4 位數據編碼由高4 位移到低4 位上 ;
        MOV A,33H
        SWAP A
        MOV 33H,A
        MOV A,30H
        SWAP A
        MOV 30H,A
        SETB ENABLE_DETE
        SETB RECEIVE  ;;
        AJMP REMOTE_END_1
        END

四、硬件抗干擾

在無線通訊中使用單片機會對通訊系統造成嚴重的干擾，相信許多技術人員一定有過同樣的苦惱。如果硬件設計不當，會造成原先硬件解碼時通訊距離為200米，而用軟件解碼后可能只有十幾米，因此解決硬件抗干擾問題在很大程度上可減少軟件解碼的誤碼率。

1、收發模塊：早期常用的頻率為47MHz，在這種頻率下，很難有好的解決方法；建議采用目前國家允許無線遙控使用的頻率315 MHz。

2、單片機振蕩頻率：大量的MCS51教材中推薦大家使用的是12MHz及11.0592MHz的晶體，這些晶體在一般場合使用沒有問題，但在此卻不可以，它們在300MHz左右仍然能夠產生較大的干擾，為解決單片機運行速度與電磁干擾的矛盾，建議采用頻率為4MHz或3.58MHz的晶體。

3、隔離：為了有效抑制單片機對接收模塊的電磁干擾，建議采用①電源隔離；②端口隔離；端口隔離可采用三極管或比較器。實踐表明采用隔離的效果非常明顯。

五、結束語

PT2262的軟件解碼在實際應用中有較好的用武之地。采用軟件解碼的系統，廠家再也無須對收發設備進行配套，以利于生產于保管；對客戶來說，使用軟件解碼無須求助，廠家只須再軟件中加入自動學習功能，用戶可自行使用該功能，只須輕按學習鍵即可學習新的通訊設備，如遙控器等。目前，該軟件解碼已經在某