描述

主條目：如何在 Arduino 中使用 NRF24L01 模塊

擁有兩個或多個 Arduino 板能夠在一定距離內以無線方式相互通信打開了許多可能性，例如遠程監控傳感器數據、控制機器人、家庭自動化等等。NRF24L01 是一種良好、可靠且廉價的解決方案。

NRF24L01+ 是 NRF24L01 的更新版本，能夠額外提供 250kbps 的空中數據速率，而沒有“+”的只有 1Mbps 和 2Mbps。只要使用 1 或 2 MBps 作為數據速率，兩個版本都可以混合使用。

NRF24L01 與 NRF24L01+PA+LNA

NRF24L01 模塊嚴格需要 3.3V，但邏輯引腳可承受 5V。這就是為什么我們推薦使用 NRF24L01 適配器作為穩壓器，保持電壓穩定，應用濾波和降低噪音。

第一個版本（左側）使用板載天線。這允許更緊湊的突破版本。使用此版本，您將能夠在 100 米的距離內進行通信（室內范圍，尤其是穿過墻壁，將略微減弱）。我們將它用于接收器。

第二個版本（右側）集成了 PA、LNA 和收發切換電路。該范圍擴展芯片與外部天線一起幫助模塊達到約 1000m。我們將它用于發射器。

該適配器對兩個版本的工作方式相同，并且具有與原始板相同的引腳排列。

接線圖

NRF24L01 模塊使用 SPI 協議與 Arduino 通信。該模塊充當 SPI 從機，這意味著它只能與具有專用 SPI 通信線路的設備一起使用。這意味著MOSI 、MISO和SCK引腳必須連接到微控制器上相應的引腳。我們使用了 Arduino Nano，這些引腳如下：

• MOSI ：Arduino Nano D11

• 味噌：Arduino Nano D12

• SCK : Arduino Nano D13

CE和CSN引腳可以分別連接到 Arduino Nano D9 和 D10（您可以使用任何引腳）。但是，D10 引腳是一個特殊引腳，必須將其設置為OUTPUT才能使Arduino Nano作為 SPI 主機運行。如果您使用不同的 Arduino 板，建議在繼續之前查看Arduino 官方文檔。

帶有 NRF24L01 的 Arduino Nano 接線

?

注意：您需要制作兩個這樣的電路。一個充當發射器，另一個充當接收器。兩者的接線是相同的。

為 nRF24L01 安裝 Arduino 庫

該庫將為您提供與模塊進行通信的接口，從而為您節省大量時間，并提供經過社區多年測試和改進的強大代碼庫。您可以從我們的官方存儲庫下載該庫。

要導入它，請打開 Arduino IDE，轉到 Sketch > Include Library > Add.ZIP Library，然后選擇剛剛下載的文件。

?

然后你可以簡單地使用include語句：

#include "RF24.h"
#include "nRF24L01.h"

它將包含具有與模塊交互的預定義函數的庫。

發射器 Arduino 代碼

我們定義了一個結構（稱為payload ），它將每INTERVAL_MS_TRANSMISSION毫秒發送一次。

• setup()函數使用提供的配置啟動模塊作為發送器。

• loop()函數將負責更新有效負載值并發送它們。

#include "SPI.h"
#include "RF24.h"
#include "nRF24L01.h"

#define CE_PIN 9
#define CSN_PIN 10

#define INTERVAL_MS_TRANSMISSION 250

RF24 radio(CE_PIN, CSN_PIN);

const byte address[6] = "00001";

//NRF24L01 buffer limit is 32 bytes (max struct size)
struct payload {
  byte data1;
  char data2;
};

payload payload;

void setup()
{
  Serial.begin(115200);

  radio.begin();

  //Append ACK packet from the receiving radio back to the transmitting radio
  radio.setAutoAck(false); //(true|false)
  //Set the transmission datarate
  radio.setDataRate(RF24_250KBPS); //(RF24_250KBPS|RF24_1MBPS|RF24_2MBPS)
  //Greater level = more consumption = longer distance
  radio.setPALevel(RF24_PA_MAX); //(RF24_PA_MIN|RF24_PA_LOW|RF24_PA_HIGH|RF24_PA_MAX)
  //Default value is the maximum 32 bytes
  radio.setPayloadSize(sizeof(payload));
  //Act as transmitter
  radio.openWritingPipe(address);
  radio.stopListening();
}

void loop()
{
  payload.data1 = 123;
  payload.data2 = 'x';

  radio.write(&payload, sizeof(payload));

  Serial.print("Data1:");
  Serial.println(payload.data1);

  Serial.print("Data2:");
  Serial.println(payload.data2);

  Serial.println("Sent");

  delay(INTERVAL_MS_TRANSMISSION);
}

接收器 Arduino 代碼

我們將監聽發送器中定義的結構（稱為payload ）。在INTERVAL_MS_SIGNAL_LOST毫秒后，連接將被視為丟失。

• setup()函數使用提供的配置啟動模塊作為接收器。

• loop()函數將負責偵聽有效負載并進行處理。

• lostConnection()函數將處理丟失的連接以防止不必要的行為。

#include "SPI.h"
#include "RF24.h"
#include "nRF24L01.h"

#define CE_PIN 9
#define CSN_PIN 10

#define INTERVAL_MS_SIGNAL_LOST 1000
#define INTERVAL_MS_SIGNAL_RETRY 250

RF24 radio(CE_PIN, CSN_PIN);

const byte address[6] = "00001";

//NRF24L01 buffer limit is 32 bytes (max struct size)
struct payload {
  byte data1;
  char data2;
};

payload payload;

unsigned long lastSignalMillis = 0;

void setup()
{
  Serial.begin(115200);

  radio.begin();

  //Append ACK packet from the receiving radio back to the transmitting radio
  radio.setAutoAck(false); //(true|false)
  //Set the transmission datarate
  radio.setDataRate(RF24_250KBPS); //(RF24_250KBPS|RF24_1MBPS|RF24_2MBPS)
  //Greater level = more consumption = longer distance
  radio.setPALevel(RF24_PA_MIN); //(RF24_PA_MIN|RF24_PA_LOW|RF24_PA_HIGH|RF24_PA_MAX)
  //Default value is the maximum 32 bytes1
  radio.setPayloadSize(sizeof(payload));
  //Act as receiver
  radio.openReadingPipe(0, address);
  radio.startListening();
}

void loop()
{
  unsigned long currentMillis = millis();

  if (radio.available() > 0) {
    radio.read(&payload, sizeof(payload));

    Serial.println("Received");

    Serial.print("Data1:");
    Serial.println(payload.data1);

    Serial.print("Data2:");
    Serial.println(payload.data2);

    lastSignalMillis = currentMillis;
  }

  if (currentMillis - lastSignalMillis > INTERVAL_MS_SIGNAL_LOST) {
    lostConnection();
  }
}

void lostConnection()
{
  Serial.println("We have lost connection, preventing unwanted behavior");

  delay(INTERVAL_MS_SIGNAL_RETRY);
}

測試

請記住，我們必須構建兩個具有相同接線的電路。

一方面，我們將上傳發射器代碼。它將生成消息有效負載并在每個INTERVAL_MS_TRANSMISSION發送它。

另一方面，我們將上傳接收方代碼。它將偵聽消息有效負載并進行處理。串行監視器將輸出類似于：

?

最后一行表示連接丟失（在沒有信號的INTERVAL_MS_SIGNAL_LOST毫秒之后）。在我們的例子中，這是一種預期的行為。在現實生活中，由于許多已知和未知的原因，信號可能會丟失，我們應該能夠控制它并采取糾正措施（在lostConnection()函數中）。