本案例使用按鈕依次切換8個(gè)輸出且可控制輸出通道，比如控制指示燈，可以輸入序號(hào)來(lái)點(diǎn)亮該序號(hào)指示燈，連接時(shí)鐘信號(hào)可以實(shí)現(xiàn)跑馬燈效果。點(diǎn)擊正向按鈕則正序依次切換指示燈，如此反復(fù)。點(diǎn)擊反向按鈕則逆序依次切換指示燈。

功能介紹

• 如果EN為FALSE，則所有輸出均為FALSE。輸入EN必須為TRUE，在E = TRUE時(shí)只有一個(gè)輸出Qn為TRUE。
• 當(dāng)E = TRUE時(shí)，使用輸入U(xiǎn)P從輸出Qn切換到Qn +1，而輸入DN將輸出Qn切換到Qn-1。
• 當(dāng)E = TRUE時(shí)，可以由SET輸入和輸入IN值選擇主動(dòng)輸出Q0..Q7。如SET=TRUE，IN=5將輸出Q5=TRUE，而所有其他輸出都設(shè)置為FALSE。
• 當(dāng)E = TRUE時(shí)，輸入RST=TRUE將輸出Q0設(shè)置為TRUE，而所有其他輸出都設(shè)置為FALSE。
• 當(dāng)E = TRUE時(shí)，狀態(tài)輸出總是顯示當(dāng)前選擇了哪個(gè)輸出Qn；當(dāng)E=FALSE時(shí)，狀態(tài)輸出保持不變，E再次變?yōu)門RUE時(shí)，Qn再次輸出。

SELECT_8源代碼

SELECT_8實(shí)現(xiàn)的是選擇器的功能，內(nèi)部調(diào)用一個(gè)取模函數(shù)INC，詳見(jiàn)下面介紹取模運(yùn)算（INC）以及其代碼。

01

取模運(yùn)算(INC)

取模是除以兩個(gè)數(shù)字時(shí)查找余數(shù)的操作。因此，當(dāng)你問(wèn)“什么是2 mod 2？”時(shí)，你是在問(wèn) “當(dāng)你把 2 除以 2 時(shí)，余數(shù)是多少？”

SELECT_8源代碼

FUNCTION_BLOCK "SELECT_8"
TITLE = 'SELECT_8'
{ S7_Optimized_Access := 'TRUE' }
VERSION : 0.1
   VAR_INPUT 
      E : Bool;
      SET : Bool;
      IN : Int;
      UP : Bool;
      DN : Bool;
      RST : Bool;
   END_VAR




   VAR_OUTPUT 
      Q0 : Bool;
      Q1 : Bool;
      Q2 : Bool;
      Q3 : Bool;
      Q4 : Bool;
      Q5 : Bool;
      Q6 : Bool;
      Q7 : Bool;
      STATE : Int;
   END_VAR




   VAR 
      last_up : Bool;
      last_dn : Bool;
   END_VAR








BEGIN


IF #RST THEN
  #STATE := 0;
ELSIF #SET THEN
  #STATE := #IN;
ELSIF #UP AND NOT #last_up THEN
  #STATE := "INC"(X := #STATE, D := 1, M := 7);
ELSIF #DN AND NOT #last_dn THEN
  #STATE := "INC"(X := #STATE, D := -1, M := 7);
END_IF;
#last_up := #UP;
#last_dn := #DN;


#Q0 := FALSE;
#Q1 := FALSE;
#Q2 := FALSE;
#Q3 := FALSE;
#Q4 := FALSE;
#Q5 := FALSE;
#Q6 := FALSE;
#Q7 := FALSE;


IF #E THEN
  CASE #STATE OF
    0:
      #Q0 := TRUE;
    1:
      #Q1 := TRUE;
    2:
      #Q2 := TRUE;
    3:
      #Q3 := TRUE;
    4:
      #Q4 := TRUE;
    5:
      #Q5 := TRUE;
    6:
      #Q6 := TRUE;
    7:
      #Q7 := TRUE;
  END_CASE;
END_IF;




END_FUNCTION_BLOCK

INC源代碼

FUNCTION "INC" : Int
{ S7_Optimized_Access := 'TRUE' }
VERSION : 0.1
   VAR_INPUT 
      X : Int;
      D : Int;
      M : Int;
   END_VAR








BEGIN


#INC := (#X + #D + #M + 1) MOD (#M + 1);
END_FUNCTION