bl2鏡像將為后續鏡像的加載執行相關的初始化操作，主要是內存、MMU、串口以及EL3軟件運行環境的設置，并且加載bl3x的鏡像到內存中。

通過查看bl2.ld.S文件可發現，bl2鏡像的入口函數是bl2_entrypoint。該函數定義在bl2/aarch64/bl2_entrypoint.S文件中。該階段的執行流程如圖所示。

bl2執行流程

bl2_entrypoint函數

bl2_entrypoint函數最終會觸發安全監控模式調用（smc） ，通知bl1將CPU的控制權限轉交給bl31，然后執行bl31。

該函數會執行

• ? 平臺相關的初始化、
• ? 獲取存放bl3x鏡像文件的結構體變量、
• ? 解析出bl31的入口地址等。

該函數的主要內容和注釋如下：

func bl2_entrypoint

            mov x20, x1                      //獲取可用安全內存的起始地址

            adr x0, early_exceptions       //設定異常向量

            msr vbar_el1, x0                //將異常向量表地址寫入到VBAR寄存器中

            isb

            msr daifclr, #DAIF_ABT_BIT    //使能SErrot中斷

            /＊ 使能指令cache、棧頂地址以及數據訪問權限對齊檢查 ＊/

            mov x1, #(SCTLR_I_BIT | SCTLR_A_BIT | SCTLR_SA_BIT)

            mrs x0, sctlr_el1

            orr x0, x0, x1

            msr sctlr_el1, x0

            isb

            /＊ 獲取有效的RW內存以備bl2使用 ＊/

              adr x0, __RW_START__                   //獲取RW內存的起始地址

              adr x1, __RW_END__                     //獲取RW內存的末端地址

              sub x1, x1, x0                          //計算出RW內存的大小

              bl  inv_dcache_range                   //禁止數據cache

              ldr x0, =__BSS_START__                 //獲取bl2中BSS段的起始地址

              ldr x1, =__BSS_SIZE__                  //獲取bl2中BSS段的大小

              bl  zeromem                              //清空BSS段中的內容

          #if USE_COHERENT_MEM

              ldr x0, =__COHERENT_RAM_START__

              ldr x1, =__COHERENT_RAM_UNALIGNED_SIZE__

              bl  zeromem

          #endif

              bl  plat_set_my_stack                  //初始化bl2運行的棧

          #if STACK_PROTECTOR_ENABLED

              bl  update_stack_protector_canary    //更新棧保護區域數據

          #endif

              mov x0, x20

              bl  bl2_early_platform_setup          //設置平臺相關

              bl  bl2_plat_arch_setup                //設置架構相關

              bl  bl2_main      //跳轉到BL2的主要函數執行，從該函數中跳轉到bl31以及bl32或者bl33

              no_ret plat_panic_handler

          endfunc bl2_entrypoint

在bl2_entrypoint函數中， 完成bl2運行棧的初始化，配置完運行環境后 ，會調用 bl2_main函數來完成bl2對bl3x鏡像的加載 ，而CPU控制權限的轉移則是通過觸發安全監控模式調用（smc）來實現。