定時器輸出PWM 實驗

一． 實驗目的
利用定時器控制產生占空比可變的PWM 波。
二． 實驗設備及器件
IBM PC 機 一臺
DP-51PROC 單片機綜合仿真實驗儀 一臺
示波器 一臺
三． 實驗內容
編寫一段程序，用P1.0 口輸出PWM 波，用D1 區的按鍵KEY1 和KEY2 實現占
空比的增加和降低。用示波器查看P1.0 口的輸出波形。
四． 實驗要求
學會使用單片機的定時器產生250Hz 的PWM 波。
五． 實驗步驟
1． 用導線連接A2 區的P11 與D1 區的KEY1。
2． 用導線連接A2 區的P12 與D1 區的KEY2。
3． 將示波器的探針連接到A2 區的P10。
4． 用示波器觀測P1.0 口的PWM 波形。
六． 實驗預習要求
認真閱讀本節的實驗內容，提前做好實驗準備工作。
七． 實驗參考程序
PWMH DATA 30H ;高電平脈沖的個數
PWM DATA 31H ;PWM周期
COUNTER DATA 32H
TEMP DATA 33H
ORG 8000H
AJMP MAIN
ORG 800BH
AJMP INTT0
ORG 8100H
MAIN:
MOV SP,#60H ;給堆棧指針賦初值
MOV PWMH,#02H
MOV COUNTER,#01H

MOV PWM,#15H
MOV TMOD,#02H ;定時器0 在模式2 下工作
MOV TL0,#38H ;定時器每200us 產生一次溢出
MOV TH0,#38H ;自動重裝的值
SETB ET0 ;使能定時器0 中斷
SETB EA ;使能總中斷
SETB TR0 ;開始計時
KSCAN:
JNB P1.1,K1CHECK ;掃描KEY1,
JNB P1.2,K2CHECK ;掃描KEY2,如果按下KEY2,跳轉到KEY2 處理
程序
SJMP KSCAN
K1CHECK:
JB P1.1,K1HANDLE ;去抖動,按下KEY1,跳轉到KEY1 處理程序
SJMP K1HANDLE
K1HANDLE:
MOV A,PWMH
CJNE A,PWM,K1H0 ;判斷是否到達上邊界
SJMP KSCAN ;是,則不進行任何操作
K1H0:
MOV A,PWMH
INC A
CJNE A,PWM,K1H1 ;如果在加1 后到達最大值
CLR TR0 ;定時器停止
SETB P1.0 ;置P1.0 為高電平
SJMP K1H2
K1H1:
CJNE A,#02H,K1H2 ;如果加1 后到達下邊界
SETB TR0 ;重開定時器
K1H2:
INC PWMH ;增加占空比
SJMP KSCAN
K2CHECK:
JB P1.2,K2HANDLE ;去抖動,按下KEY2,跳轉到KEY2 處理程序
SJMP K1HANDLE
K2HANDLE:
MOV A,PWMH
CJNE A,#01H,K2H0 ;判斷是否到達下邊界
SJMP KSCAN ;是,則不進行任何操作
K2H0:
MOV A,PWMH
MOV TEMP,PWM
DEC A

CJNE A,#01H,K2H1 ;如果在減1 后到達下邊界
CLR TR0 ;定時器停止
CLR P1.0 ;置P1.0 為低電平
SJMP K2H2
K2H1:
DEC TEMP
CJNE A,TEMP,K2H2 ;如果到達上邊界
SETB TR0 ;啟動定時器
K2H2:
DEC PWMH ;降低占空比
SJMP KSCAN
INTT0:
PUSH PSW ;現場保護
PUSH ACC
INC COUNTER ;計數值加1
MOV A,COUNTER
CJNE A,PWMH,INTT01 ;如果等于高電平脈沖數
CLR P1.0 ;P1.0 變為低電平
INTT01:
CJNE A,PWM,INTT02 ;如果等于周期數
MOV COUNTER,#01H ;計數器復位
SETB P1.0 ;置P1.0 為高電平
INTT02:
POP ACC ;出棧
POP PSW
RETI；
END
八． 實驗思考題
（1）請用戶思考一下，用另一種方式實現定時器產生PWM 波。